blob: bec093e8d3f0d67163a90c48a251fc0744976917 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
|
{
config,
lib,
...
}: let
inherit (lib) mkOption mkEnableOption types mkIf mkForce mkMerge hostapd elemAt;
cnf = config.cynerd.wifiAP.spt;
wifi-networks = name: let
is2g = cnf."${name}".channel <= 14;
in {
"${cnf."${name}".interface}" = {
bssid = elemAt cnf."${name}".bssids 0;
ssid = "TurrisRules${
if is2g
then ""
else "5"
}";
authentication = {
mode = "wpa2-sha256";
wpaPasswordFile = "/run/secrets/hostapd-TurrisRules.pass";
};
settings = mkIf is2g {
ieee80211w = 0;
wpa_key_mgmt = mkForce "WPA-PSK"; # force use without sha256
};
};
"${cnf."${name}".interface}.guest" = {
bssid = elemAt cnf."${name}".bssids 1;
ssid = "Kocovi";
authentication = {
mode = "wpa2-sha256";
wpaPasswordFile = "/run/secrets/hostapd-Kocovi.pass";
};
};
};
net-networks = name: {
"lan-${cnf."${name}".interface}" = {
matchConfig = {
Name = cnf."${name}".interface;
WLANInterfaceType = "ap";
};
networkConfig.Bridge = "brlan";
bridgeVLANs = [
{
EgressUntagged = 1;
PVID = 1;
}
];
};
"lan-${cnf."${name}".interface}-guest" = {
matchConfig.Name = "${cnf."${name}".interface}.guest";
networkConfig.Bridge = "brlan";
bridgeVLANs = [
{
EgressUntagged = 2;
PVID = 2;
}
];
};
};
wOptions = card: channelDefault: {
interface = mkOption {
type = with types; nullOr str;
default = null;
description = "Specify interface for ${card}";
};
bssids = mkOption {
type = with types; listOf str;
default = [];
description = "BSSIDs for networks.";
};
channel = mkOption {
type = types.ints.positive;
default = channelDefault;
description = "Channel to be used for ${card}";
};
};
in {
options = {
cynerd.wifiAP.spt = {
enable = mkEnableOption "Enable Wi-Fi Access Point support";
ar9287 = wOptions "Qualcom Atheros AR9287" 7;
qca988x = wOptions "Qualcom Atheros QCA988x" 36;
};
};
config = mkIf cnf.enable {
# TODO regdom doesn't work for some reason
boot.extraModprobeConfig = ''
options cfg80211 ieee80211_regdom="CZ"
'';
services.hostapd = {
enable = true;
radios = mkMerge [
(mkIf (cnf.ar9287.interface != null) {
"${cnf.ar9287.interface}" = {
inherit (cnf.ar9287) channel;
countryCode = "CZ";
wifi4 = {
enable = true;
inherit (hostapd.qualcomAtherosAR9287.wifi4) capabilities;
};
networks = wifi-networks "ar9287";
};
})
(mkIf (cnf.qca988x.interface != null) {
"${cnf.qca988x.interface}" = let
is2g = cnf.qca988x.channel <= 14;
in {
inherit (cnf.qca988x) channel;
countryCode = "CZ";
band =
if is2g
then "2g"
else "5g";
wifi4 = {
enable = true;
inherit (hostapd.qualcomAtherosQCA988x.wifi4) capabilities;
};
wifi5 = {
enable = !is2g;
inherit (hostapd.qualcomAtherosQCA988x.wifi5) capabilities;
};
networks = wifi-networks "qca988x";
};
})
];
};
systemd.network.networks = mkMerge [
(mkIf (cnf.ar9287.interface != null) (net-networks "ar9287"))
(mkIf (cnf.qca988x.interface != null) (net-networks "qca988x"))
];
};
}
|
