blob: c1a017c3ee717b09573fd4a8f8b86f263b0ff132 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
|
{
description = "Cynerd's personal flake";
inputs = {
shellrc.url = "git+https://git.cynerd.cz/shellrc";
personal-secret.url = "git+ssh://git@cynerd.cz/nixos-personal-secret";
nixturris = {
url = "git+https://git.cynerd.cz/nixturris";
inputs.nixpkgs.follows = "nixpkgs";
};
sterm.url = "github:wentasah/sterm";
};
outputs = { self
, nixpkgs, flake-utils, nixos-hardware
, shellrc, nixturris, personal-secret
, sterm
}:
with flake-utils.lib;
{
overlays.default = final: prev: import ./pkgs { inherit self; nixpkgs = prev; };
nixosModules = import ./nixos nixpkgs;
nixosConfigurations = let
modules = hostname: [
self.nixosModules.default
self.nixosModules."machine-${hostname}"
shellrc.nixosModules.default
(personal-secret.lib.personalSecrets hostname)
{
networking.hostName = hostname;
nixpkgs.overlays = [
self.overlays.default
sterm.overlay
];
}
];
genericSystem = {system, extra_modules ? []}: hostname: {
${hostname} = nixpkgs.lib.nixosSystem {
system = system;
modules = (modules hostname) ++ extra_modules;
};
};
amd64System = genericSystem {system = "x86_64-linux";};
raspi2System = genericSystem {system = "armv7l-linux"; extra_modules = [
nixos-hardware.nixosModules.raspberry-pi-2
nixturris.nixosModules.turris-crossbuild
nixturris.nixosModules.armv7l-overlay
{ boot.loader.systemd-boot.enable = false; }
];};
raspi3System = genericSystem {system = "aarch64-linux"; extra_modules = [
({pkgs, ...}: {
boot.loader.systemd-boot.enable = false;
boot.loader.grub.enable = false;
boot.loader.generic-extlinux-compatible.enable = true;
#boot.kernelPackages = pkgs.linuxKernel.packages.linux_rpi3;
})
];};
beagleboneSystem = genericSystem {system = "armv7l-linux"; extra_modules = [
nixturris.nixosModules.turris-crossbuild
nixturris.nixosModules.armv7l-overlay
# TODO
];};
turrisSystem = board: hostname: {
${hostname} = nixturris.lib.nixturrisSystem {
nixpkgs = nixpkgs;
board = board;
modules = modules hostname;
};
};
turrisMoxSystem = turrisSystem "mox";
turrisOmniaSystem = turrisSystem "omnia";
in
amd64System "albert" //
amd64System "binky" //
amd64System "errol" //
amd64System "lipwig" //
amd64System "ridcully" //
amd64System "susan" //
raspi2System "spt-mpd" //
raspi3System "adm-mpd" //
beagleboneSystem "gaspode" //
turrisMoxSystem "dean" //
turrisOmniaSystem "spt-omnia" //
turrisMoxSystem "spt-mox" //
turrisMoxSystem "spt-mox2" //
turrisOmniaSystem "adm-omnia" //
turrisOmniaSystem "adm-omnia2";
} // eachDefaultSystem (system: {
packages = filterPackages system (flattenTree (
import ./pkgs { inherit self; nixpkgs = nixpkgs.legacyPackages."${system}"; }
));
devShells = filterPackages system
(import ./devShells { inherit nixpkgs; inherit shellrc; inherit system; });
});
}
|
