2 files changed, 132 insertions, 0 deletions
diff --git a/vim/bundle/syntastic/syntax_checkers/lua/luac.vim b/vim/bundle/syntastic/syntax_checkers/lua/luac.vim
new file mode 100644
index 0000000..178f76a
--- /dev/null
+++ b/vim/bundle/syntastic/syntax_checkers/lua/luac.vim
@@ -0,0 +1,65 @@
+"============================================================================
+"File:        lua.vim
+"Description: Syntax checking plugin for syntastic.vim
+"Maintainer:  Gregor Uhlenheuer <kongo2002 at gmail dot com>
+"License:     This program is free software. It comes without any warranty,
+"             to the extent permitted by applicable law. You can redistribute
+"             it and/or modify it under the terms of the Do What The Fuck You
+"             Want To Public License, Version 2, as published by Sam Hocevar.
+"             See http://sam.zoy.org/wtfpl/COPYING for more details.
+"
+"============================================================================
+
+if exists('g:loaded_syntastic_lua_luac_checker')
+    finish
+endif
+let g:loaded_syntastic_lua_luac_checker = 1
+
+let s:save_cpo = &cpo
+set cpo&vim
+
+function! SyntaxCheckers_lua_luac_GetHighlightRegex(pos)
+    let result = ''
+    let near = matchstr(a:pos['text'], '\mnear ''\zs[^'']\+\ze''')
+    if near !=# ''
+        if near ==# '<eof>'
+            let p = getpos('$')
+            let a:pos['lnum'] = p[1]
+            let a:pos['col'] = p[2]
+            let result = '\%' . p[2] . 'c'
+        else
+            let result = '\V' . escape(near, '\')
+        endif
+
+        " XXX the following piece of code is evil, and is likely to break
+        " in future versions of syntastic; enable it at your own risk :)
+
+        "let open = matchstr(a:pos['text'], '\m(to close ''\zs[^'']\+\ze'' at line [0-9]\+)')
+        "if open != ''
+        "    let line = str2nr(matchstr(a:pos['text'], '\m(to close ''[^'']\+'' at line \zs[0-9]\+\ze)'))
+        "    let group = a:pos['type'] ==? 'E' ? 'SyntasticError' : 'SyntasticWarning'
+        "    call matchadd(group, '\%' . line . 'l\V' . escape(open, '\'))
+        "endif
+    endif
+    return result
+endfunction
+
+function! SyntaxCheckers_lua_luac_GetLocList() dict
+    let makeprg = self.makeprgBuild({ 'args_after': '-p' })
+
+    let errorformat = 'luac: %#%f:%l: %m'
+
+    return SyntasticMake({
+        \ 'makeprg': makeprg,
+        \ 'errorformat': errorformat,
+        \ 'defaults': { 'bufnr': bufnr(''), 'type': 'E' } })
+endfunction
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'lua',
+    \ 'name': 'luac'})
+
+let &cpo = s:save_cpo
+unlet s:save_cpo
+
+" vim: set sw=4 sts=4 et fdm=marker:
diff --git a/vim/bundle/syntastic/syntax_checkers/lua/luacheck.vim b/vim/bundle/syntastic/syntax_checkers/lua/luacheck.vim
new file mode 100644
index 0000000..5c8521d
--- /dev/null
+++ b/vim/bundle/syntastic/syntax_checkers/lua/luacheck.vim
@@ -0,0 +1,67 @@
+"============================================================================
+"File:        luacheck.vim
+"Description: Lua static analysis using luacheck
+"Maintainer:  Thiago Bastos <tbastos@tbastos.com>
+"License:     This program is free software. It comes without any warranty,
+"             to the extent permitted by applicable law. You can redistribute
+"             it and/or modify it under the terms of the Do What The Fuck You
+"             Want To Public License, Version 2, as published by Sam Hocevar.
+"             See http://sam.zoy.org/wtfpl/COPYING for more details.
+"============================================================================
+
+if exists('g:loaded_syntastic_lua_luacheck_checker')
+    finish
+endif
+let g:loaded_syntastic_lua_luacheck_checker = 1
+
+let s:save_cpo = &cpo
+set cpo&vim
+
+function! SyntaxCheckers_lua_luacheck_GetHighlightRegex(item)
+    let term = matchstr(a:item['text'], '\m''\zs\S\+\ze''')
+    if term !=# ''
+        return '\V\<' . escape(term, '\') . '\>'
+    endif
+
+    let term = matchstr(a:item['text'], '\m\(accessing undefined\|setting non-standard global\|' .
+                \ 'setting non-module global\|unused global\) variable \zs\S\+')
+    if term ==# ''
+        let term = matchstr(a:item['text'], '\mvariable \zs\S\+\ze was previously defined')
+    endif
+    if term ==# ''
+        let term = matchstr(a:item['text'], '\munused \(variable\|argument\|loop variable\) \zs\S\+')
+    endif
+    if term ==# ''
+        let term = matchstr(a:item['text'], '\m\(value assigned to variable\|value of argument\|' .
+                \ 'value of loop variable\) \zs\S\+')
+    endif
+    if term ==# ''
+        let term = matchstr(a:item['text'], '\mvariable \zs\S\+\ze is never set')
+    endif
+
+    return term !=# '' ? '\V\<' . escape(term, '\') . '\>' : ''
+endfunction
+
+function! SyntaxCheckers_lua_luacheck_GetLocList() dict
+    let makeprg = self.makeprgBuild({ 'args_after': '--no-color' })
+
+    let errorformat =
+        \ '%f:%l:%c: %m,'.
+        \ '%-G%.%#'
+
+    return SyntasticMake({
+        \ 'makeprg': makeprg,
+        \ 'errorformat': errorformat,
+        \ 'subtype': 'Style',
+        \ 'defaults': { 'type': 'W' },
+        \ 'returns': [0, 1, 2] })
+endfunction
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'lua',
+    \ 'name': 'luacheck' })
+
+let &cpo = s:save_cpo
+unlet s:save_cpo
+
+" vim: set sw=4 sts=4 et fdm=marker: