Remove webkit as this version is now in upstream

6 files changed, 0 insertions, 325 deletions

diff --git a/net-libs/libwpe/Manifest b/net-libs/libwpe/Manifest
deleted file mode 100644
index f27fd2b..0000000
--- a/net-libs/libwpe/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST libwpe-1.4.0.1.tar.xz 49636 BLAKE2B 6fc9d6865873c7c16be3c959316539ecd4f08ae91dac003a46ca91e34503810cab089c9b609318b32919c02e111e209b68874aba0b6730e71b2e51fb75498656 SHA512 cbbe6b8e9bbb864d7f96bbdb56db262bbd341c86bc7bedfcc51be8077c0ea58a4e88c61b7b7bec937d5476e6cb81c093229bf80e3ee99452829287bd26175670
diff --git a/net-libs/libwpe/libwpe-1.4.0.1.ebuild b/net-libs/libwpe/libwpe-1.4.0.1.ebuild
deleted file mode 100644
index b8f264c..0000000
--- a/net-libs/libwpe/libwpe-1.4.0.1.ebuild
+++ /dev/null
@@ -1,17 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit cmake-utils
-
-DESCRIPTION="General-purpose library for WPE WebKit"
-HOMEPAGE="https://www.wpewebkit.org"
-SRC_URI="https://www.wpewebkit.org/releases/${P}.tar.xz"
-
-LICENSE="LGPL-2+ BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="x11-libs/libxkbcommon"
-DEPEND="${RDEPEND}"
diff --git a/net-libs/webkit-gtk/Manifest b/net-libs/webkit-gtk/Manifest
deleted file mode 100644
index 6814f53..0000000
--- a/net-libs/webkit-gtk/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST webkitgtk-2.26.3.tar.xz 19331900 BLAKE2B 14c31b0f640b0f859a3c1eeda542f176f6c7981270c5be3225556eb4a1027a2511039cf0f33682faa93846c4ca5ed64158574a9b8a662a4a200b97cad28d5ed0 SHA512 9575c86ab5752c09841878cf55134e7de9a87200e55017859cd02affb1cadd58031a7b6f67a580e87a1dfe4fc830fed9774ba289e7244d3ead9eb9328e76d7c9
diff --git a/net-libs/webkit-gtk/webkit-gtk-2.26.3.ebuild b/net-libs/webkit-gtk/webkit-gtk-2.26.3.ebuild
deleted file mode 100644
index 2e380f0..0000000
--- a/net-libs/webkit-gtk/webkit-gtk-2.26.3.ebuild
+++ /dev/null
@@ -1,284 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-CMAKE_MAKEFILE_GENERATOR="ninja"
-PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
-USE_RUBY="ruby24 ruby25 ruby26"
-
-inherit check-reqs cmake-utils flag-o-matic gnome2 pax-utils python-any-r1 ruby-single toolchain-funcs virtualx
-
-MY_P="webkitgtk-${PV}"
-DESCRIPTION="Open source web browser engine"
-HOMEPAGE="https://www.webkitgtk.org"
-SRC_URI="https://www.webkitgtk.org/releases/${MY_P}.tar.xz"
-
-LICENSE="LGPL-2+ BSD"
-SLOT="4/39" # soname version of libwebkit2gtk-4.0
-KEYWORDS="~alpha amd64 ~arm arm64 ~ia64 ~ppc ~ppc64 ~sparc x86 ~amd64-fbsd ~amd64-linux ~x86-linux ~x86-macos"
-
-IUSE="aqua coverage doc +egl +geolocation gles2 gnome-keyring +gstreamer +introspection +jpeg2k libnotify nsplugin +opengl spell wayland +webgl +X"
-
-# webgl needs gstreamer, bug #560612
-# gstreamer with opengl/gles2 needs egl
-REQUIRED_USE="
-	geolocation? ( introspection )
-	gles2? ( egl !opengl )
-	gstreamer? ( opengl? ( egl ) )
-	nsplugin? ( X )
-	webgl? ( gstreamer
-		|| ( gles2 opengl ) )
-	wayland? ( egl )
-	|| ( aqua wayland X )
-"
-
-# Tests fail to link for inexplicable reasons
-# https://bugs.webkit.org/show_bug.cgi?id=148210
-RESTRICT="test"
-
-# Aqua support in gtk3 is untested
-# Dependencies found at Source/cmake/OptionsGTK.cmake
-# Various compile-time optionals for gtk+-3.22.0 - ensure it
-# Missing OpenWebRTC checks and conditionals, but ENABLE_MEDIA_STREAM/ENABLE_WEB_RTC is experimental upstream (PRIVATE OFF)
-# >=gst-plugins-opus-1.14.4-r1 for opusparse (required by MSE)
-RDEPEND="
-	>=x11-libs/cairo-1.16.0:=[X?]
-	>=media-libs/fontconfig-2.13.0:1.0
-	>=media-libs/freetype-2.9.0:2
-	>=dev-libs/libgcrypt-1.7.0:0=
-	>=x11-libs/gtk+-3.22:3[aqua?,introspection?,wayland?,X?]
-	>=media-libs/harfbuzz-1.4.2:=[icu(+)]
-	>=dev-libs/icu-3.8.1-r1:=
-	virtual/jpeg:0=
-	>=net-libs/libsoup-2.48:2.4[introspection?]
-	>=dev-libs/libxml2-2.8.0:2
-	>=media-libs/libpng-1.4:0=
-	dev-db/sqlite:3=
-	sys-libs/zlib:0
-	>=dev-libs/atk-2.8.0
-	media-libs/libwebp:=
-	net-libs/libwpe
-	net-libs/wpebackend-fdo
-
-	>=dev-libs/glib-2.40:2
-	>=dev-libs/libxslt-1.1.7
-	media-libs/woff2
-	gnome-keyring? ( app-crypt/libsecret )
-	geolocation? ( >=app-misc/geoclue-2.1.5:2.0 )
-	introspection? ( >=dev-libs/gobject-introspection-1.32.0:= )
-	dev-libs/libtasn1:=
-	nsplugin? ( >=x11-libs/gtk+-2.24.10:2 )
-	spell? ( >=app-text/enchant-0.22:= )
-	gstreamer? (
-		>=media-libs/gstreamer-1.14:1.0
-		>=media-libs/gst-plugins-base-1.14:1.0[egl?,gles2?,opengl?]
-		>=media-plugins/gst-plugins-opus-1.14.4-r1:1.0
-		>=media-libs/gst-plugins-bad-1.14:1.0 )
-
-	X? (
-		x11-libs/libX11
-		x11-libs/libXcomposite
-		x11-libs/libXdamage
-		x11-libs/libXrender
-		x11-libs/libXt )
-
-	libnotify? ( x11-libs/libnotify )
-	dev-libs/hyphen
-	jpeg2k? ( >=media-libs/openjpeg-2.2.0:2= )
-
-	egl? ( media-libs/mesa[egl] )
-	gles2? ( media-libs/mesa[gles2] )
-	opengl? ( virtual/opengl )
-	webgl? (
-		x11-libs/libXcomposite
-		x11-libs/libXdamage )
-"
-
-# paxctl needed for bug #407085
-# Need real bison, not yacc
-DEPEND="${RDEPEND}
-	${PYTHON_DEPS}
-	${RUBY_DEPS}
-	>=app-accessibility/at-spi2-core-2.5.3
-	dev-util/glib-utils
-	>=dev-util/gtk-doc-am-1.10
-	>=dev-util/gperf-3.0.1
-	>=sys-devel/bison-2.4.3
-	|| ( >=sys-devel/gcc-6.0 >=sys-devel/clang-3.3 )
-	sys-devel/gettext
-	virtual/pkgconfig
-
-	>=dev-lang/perl-5.10
-	virtual/perl-Data-Dumper
-	virtual/perl-Carp
-	virtual/perl-JSON-PP
-
-	doc? ( >=dev-util/gtk-doc-1.10 )
-	geolocation? ( dev-util/gdbus-codegen )
-"
-#	test? (
-#		dev-python/pygobject:3[python_targets_python2_7]
-#		x11-themes/hicolor-icon-theme
-#		jit? ( sys-apps/paxctl ) )
-
-S="${WORKDIR}/${MY_P}"
-
-CHECKREQS_DISK_BUILD="18G" # and even this might not be enough, bug #417307
-
-pkg_pretend() {
-	if [[ ${MERGE_TYPE} != "binary" ]] ; then
-		if is-flagq "-g*" && ! is-flagq "-g*0" ; then
-			einfo "Checking for sufficient disk space to build ${PN} with debugging CFLAGS"
-			check-reqs_pkg_pretend
-		fi
-
-		if ! test-flag-CXX -std=c++11 ; then
-			die "You need at least GCC 4.9.x or Clang >= 3.3 for C++11-specific compiler flags"
-		fi
-
-		if tc-is-gcc && [[ $(gcc-version) < 4.9 ]] ; then
-			die 'The active compiler needs to be gcc 4.9 (or newer)'
-		fi
-	fi
-
-	if ! use opengl && ! use gles2; then
-		ewarn
-		ewarn "You are disabling OpenGL usage (USE=opengl or USE=gles) completely."
-		ewarn "This is an unsupported configuration meant for very specific embedded"
-		ewarn "use cases, where there truly is no GL possible (and even that use case"
-		ewarn "is very unlikely to come by). If you have GL (even software-only), you"
-		ewarn "really really should be enabling OpenGL!"
-		ewarn
-	fi
-}
-
-pkg_setup() {
-	if [[ ${MERGE_TYPE} != "binary" ]] && is-flagq "-g*" && ! is-flagq "-g*0" ; then
-		check-reqs_pkg_setup
-	fi
-
-	python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	cmake-utils_src_prepare
-	gnome2_src_prepare
-}
-
-src_configure() {
-	# Respect CC, otherwise fails on prefix #395875
-	tc-export CC
-
-	# It does not compile on alpha without this in LDFLAGS
-	# https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=648761
-	use alpha && append-ldflags "-Wl,--no-relax"
-
-	# ld segfaults on ia64 with LDFLAGS --as-needed, bug #555504
-	use ia64 && append-ldflags "-Wl,--no-as-needed"
-
-	# Sigbuses on SPARC with mcpu and co., bug #???
-	use sparc && filter-flags "-mvis"
-
-	# https://bugs.webkit.org/show_bug.cgi?id=42070 , #301634
-	use ppc64 && append-flags "-mminimal-toc"
-
-	# Try to use less memory, bug #469942 (see Fedora .spec for reference)
-	# --no-keep-memory doesn't work on ia64, bug #502492
-	if ! use ia64; then
-		append-ldflags "-Wl,--no-keep-memory"
-	fi
-
-	# We try to use gold when possible for this package
-#	if ! tc-ld-is-gold ; then
-#		append-ldflags "-Wl,--reduce-memory-overheads"
-#	fi
-
-	# Multiple rendering bugs on youtube, github, etc without this, bug #547224
-	append-flags $(test-flags -fno-strict-aliasing)
-
-	# Ruby situation is a bit complicated. See bug 513888
-	local rubyimpl
-	local ruby_interpreter=""
-	for rubyimpl in ${USE_RUBY}; do
-		if has_version "virtual/rubygems[ruby_targets_${rubyimpl}]"; then
-			ruby_interpreter="-DRUBY_EXECUTABLE=$(type -P ${rubyimpl})"
-		fi
-	done
-	# This will rarely occur. Only a couple of corner cases could lead us to
-	# that failure. See bug 513888
-	[[ -z $ruby_interpreter ]] && die "No suitable ruby interpreter found"
-
-	# TODO: Check Web Audio support
-	# should somehow let user select between them?
-	#
-	# FTL_JIT requires llvm
-	#
-	# opengl needs to be explicetly handled, bug #576634
-
-	local opengl_enabled
-	if use opengl || use gles2; then
-		opengl_enabled=ON
-	else
-		opengl_enabled=OFF
-	fi
-
-	local mycmakeargs=(
-		#-DENABLE_UNIFIED_BUILDS=$(usex jumbo-build) # broken in 2.24.1
-		-DENABLE_QUARTZ_TARGET=$(usex aqua)
-		-DENABLE_API_TESTS=$(usex test)
-		-DENABLE_GTKDOC=$(usex doc)
-		-DENABLE_GEOLOCATION=$(usex geolocation)
-		$(cmake-utils_use_find_package gles2 OpenGLES2)
-		-DENABLE_GLES2=$(usex gles2)
-		-DENABLE_VIDEO=$(usex gstreamer)
-		-DENABLE_WEB_AUDIO=$(usex gstreamer)
-		-DENABLE_INTROSPECTION=$(usex introspection)
-		-DUSE_LIBNOTIFY=$(usex libnotify)
-		-DUSE_LIBSECRET=$(usex gnome-keyring)
-		-DUSE_OPENJPEG=$(usex jpeg2k)
-		-DUSE_WOFF2=ON
-		-DENABLE_PLUGIN_PROCESS_GTK2=$(usex nsplugin)
-		-DENABLE_SPELLCHECK=$(usex spell)
-		-DENABLE_WAYLAND_TARGET=$(usex wayland)
-		-DENABLE_WEBGL=$(usex webgl)
-		$(cmake-utils_use_find_package egl EGL)
-		$(cmake-utils_use_find_package opengl OpenGL)
-		-DENABLE_X11_TARGET=$(usex X)
-		-DENABLE_OPENGL=${opengl_enabled}
-		-DCMAKE_BUILD_TYPE=Release
-		-DPORT=GTK
-		-DENABLE_BUBBLEWRAP_SANDBOX=n
-		${ruby_interpreter}
-	)
-
-	# Allow it to use GOLD when possible as it has all the magic to
-	# detect when to use it and using gold for this concrete package has
-	# multiple advantages and is also the upstream default, bug #585788
-#	if tc-ld-is-gold ; then
-#		mycmakeargs+=( -DUSE_LD_GOLD=ON )
-#	else
-#		mycmakeargs+=( -DUSE_LD_GOLD=OFF )
-#	fi
-
-	cmake-utils_src_configure
-}
-
-src_compile() {
-	cmake-utils_src_compile
-}
-
-src_test() {
-	# Prevents test failures on PaX systems
-	pax-mark m $(list-paxables Programs/*[Tt]ests/*) # Programs/unittests/.libs/test*
-
-	cmake-utils_src_test
-}
-
-src_install() {
-	cmake-utils_src_install
-
-	# Prevents crashes on PaX systems, bug #522808
-	pax-mark m "${ED}usr/libexec/webkit2gtk-4.0/jsc" "${ED}usr/libexec/webkit2gtk-4.0/WebKitWebProcess"
-	pax-mark m "${ED}usr/libexec/webkit2gtk-4.0/WebKitPluginProcess"
-	use nsplugin && pax-mark m "${ED}usr/libexec/webkit2gtk-4.0/WebKitPluginProcess"2
-}
diff --git a/net-libs/wpebackend-fdo/Manifest b/net-libs/wpebackend-fdo/Manifest
deleted file mode 100644
index 2d5bfe4..0000000
--- a/net-libs/wpebackend-fdo/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST wpebackend-fdo-1.4.0.tar.xz 30204 BLAKE2B dda32e0408a8fd98dc1d03c4606e20fb219fe722aef24360e31cd62027601a4795dbdbf026925e284e6b87f223e6e79824e8e6bab181b7bbf42a9db0664358dc SHA512 f94167b13345adfda15312b16e5de04910f812c7481f7e3c8a00163ce8387be22373867b51b2c5cb424e62de877c1aaa48592aac85ec9cc03c969c7e83185660
diff --git a/net-libs/wpebackend-fdo/wpebackend-fdo-1.4.0.ebuild b/net-libs/wpebackend-fdo/wpebackend-fdo-1.4.0.ebuild
deleted file mode 100644
index 6737799..0000000
--- a/net-libs/wpebackend-fdo/wpebackend-fdo-1.4.0.ebuild
+++ /dev/null
@@ -1,21 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit cmake-utils
-
-DESCRIPTION="General-purpose library for WPE WebKit"
-HOMEPAGE="https://www.wpewebkit.org"
-SRC_URI="https://www.wpewebkit.org/releases/${P}.tar.xz"
-
-LICENSE="LGPL-2+ BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="
-	>=dev-libs/glib-2
-	media-libs/mesa[egl]
-	dev-libs/wayland
-	net-libs/libwpe"
-DEPEND="${RDEPEND}"