Add gst plugins with experimental use flag

9 files changed, 303 insertions, 0 deletions

diff --git a/media-libs/gst-plugins-bad/Manifest b/media-libs/gst-plugins-bad/Manifest
new file mode 100644
index 0000000..5a6998c
--- /dev/null
+++ b/media-libs/gst-plugins-bad/Manifest
@@ -0,0 +1 @@
+DIST gst-plugins-bad-1.12.3.tar.xz 4707000 SHA256 36d059761852bed0f1a7fcd3ef64a8aeecab95d2bca53cd6aa0f08054b1cbfec SHA512 6df47381de3a2f4286d047c1e7de2c76dd4312c9806636e2012717282cde0f3e5b2d0ffa910c564c8e122b19363e842b663cce1eda7ae95a05d63d1dbbd52661 WHIRLPOOL b4c1262a0ca63331f5cb38fecc6a26830234712d6d4409aed495b05e7cfe13760bf056767e54e17cb9899c3671f0a05b90199d80d0b47bacb2ee6d27b89a5457
diff --git a/media-libs/gst-plugins-bad/gst-plugins-bad-1.12.3-r1.ebuild b/media-libs/gst-plugins-bad/gst-plugins-bad-1.12.3-r1.ebuild
new file mode 100644
index 0000000..0ac832a
--- /dev/null
+++ b/media-libs/gst-plugins-bad/gst-plugins-bad-1.12.3-r1.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GST_ORG_MODULE="gst-plugins-bad"
+
+inherit eutils flag-o-matic gstreamer virtualx
+
+DESCRIPTION="Less plugins for GStreamer"
+HOMEPAGE="https://gstreamer.freedesktop.org/"
+
+LICENSE="LGPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+
+IUSE="X bzip2 egl gles2 gtk +introspection opengl +orc vcd vnc wayland +experimental"
+REQUIRED_USE="
+	gles2? ( !opengl )
+	opengl? ( X )
+	wayland? ( egl )
+"
+
+# X11 is automagic for now, upstream #709530
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-${PV}:${SLOT}[${MULTILIB_USEDEP},introspection?]
+	>=media-libs/gst-plugins-base-${PV}:${SLOT}[${MULTILIB_USEDEP},introspection?]
+	introspection? ( >=dev-libs/gobject-introspection-1.31.1:= )
+
+	bzip2? ( >=app-arch/bzip2-1.0.6-r4[${MULTILIB_USEDEP}] )
+	egl? ( >=media-libs/mesa-9.1.6[egl,${MULTILIB_USEDEP}] )
+	gles2? ( >=media-libs/mesa-9.1.6[gles2,${MULTILIB_USEDEP}] )
+	opengl? (
+		>=media-libs/mesa-9.1.6[${MULTILIB_USEDEP}]
+		virtual/glu[${MULTILIB_USEDEP}] )
+	X? ( x11-libs/libX11[${MULTILIB_USEDEP}] )
+	wayland? (
+		>=dev-libs/wayland-1.4.0[${MULTILIB_USEDEP}]
+		>=x11-libs/libdrm-2.4.55[${MULTILIB_USEDEP}]
+		>=dev-libs/wayland-protocols-1.4
+	)
+
+	gtk? ( >=x11-libs/gtk+-3.15:3[X?,wayland?,${MULTILIB_USEDEP}] )
+	orc? ( >=dev-lang/orc-0.4.17[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.12
+"
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+	addpredict /dev # Prevent sandbox violations bug #570624
+}
+
+multilib_src_configure() {
+	local myconf=()
+	if use opengl || use gles2 ; then
+		# Actually enable the gl element, not just libs
+		myconf+=( --enable-gl )
+	fi
+
+	# Always enable gsettings (no extra dependency)
+	# and shm (need a switch for winnt ?)
+	gstreamer_multilib_src_configure \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable experimental) \
+		$(use_enable bzip2 bz2) \
+		$(use_enable egl) \
+		$(use_enable gles2) \
+		$(use_enable gtk gtk3) \
+		$(use_enable opengl) \
+		$(use_enable opengl glx) \
+		$(use_enable orc) \
+		$(use_enable vcd) \
+		$(use_enable vnc librfb) \
+		$(use_enable wayland) \
+		$(use_enable X x11) \
+		--disable-examples \
+		--disable-debug \
+		--disable-cocoa \
+		--without-player-tests \
+		--disable-wgl \
+		--enable-shm \
+		${myconf[$@]}
+		# not ported
+		# --enable-gsettings
+
+	if multilib_is_native_abi; then
+		local x
+		for x in libs plugins; do
+			ln -s "${S}"/docs/${x}/html docs/${x}/html || die
+		done
+	fi
+}
+
+multilib_src_test() {
+	unset DISPLAY
+	# Tests are slower than upstream expects
+	virtx emake check CK_DEFAULT_TIMEOUT=300
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS ChangeLog NEWS README RELEASE"
+	einstalldocs
+	prune_libtool_files --modules
+}
diff --git a/media-libs/gst-plugins-base/Manifest b/media-libs/gst-plugins-base/Manifest
new file mode 100644
index 0000000..ffd18f8
--- /dev/null
+++ b/media-libs/gst-plugins-base/Manifest
@@ -0,0 +1 @@
+DIST gst-plugins-base-1.12.3.tar.xz 3117364 SHA256 d3d37b8489d37fa0018973d850bd2067b98af335fef2fa543ee7d40359e3cea5 SHA512 d32f71836e25081b00040709a2184da85489e5af90902a0b27b820a478f5805bde93a04cefaeabf36dde53c16ad12f2816777cc195f1e027f19d1883e088e2b2 WHIRLPOOL e81c3183a70b121412bc455a4f93501e2fab7bf241a66f903446115891ab66ee78d570b01a4eaa5eb7971a7233f3fabf10a71c398bb4205beea6dbfb4280bcdf
diff --git a/media-libs/gst-plugins-base/gst-plugins-base-1.12.3-r1.ebuild b/media-libs/gst-plugins-base/gst-plugins-base-1.12.3-r1.ebuild
new file mode 100644
index 0000000..2bb4d82
--- /dev/null
+++ b/media-libs/gst-plugins-base/gst-plugins-base-1.12.3-r1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GST_ORG_MODULE="gst-plugins-base"
+
+inherit gstreamer
+
+DESCRIPTION="Basepack of plugins for gstreamer"
+HOMEPAGE="https://gstreamer.freedesktop.org/"
+
+LICENSE="GPL-2+ LGPL-2+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+
+IUSE="alsa +introspection ivorbis +ogg +orc +pango theora +vorbis X +experimental"
+REQUIRED_USE="
+	ivorbis? ( ogg )
+	theora? ( ogg )
+	vorbis? ( ogg )
+"
+
+RDEPEND="
+	app-text/iso-codes
+	>=dev-libs/glib-2.40.0:2[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-${PV}:1.0[introspection?,${MULTILIB_USEDEP}]
+	>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+	alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.31.1:= )
+	ivorbis? ( >=media-libs/tremor-0_pre20130223[${MULTILIB_USEDEP}] )
+	ogg? ( >=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}] )
+	orc? ( >=dev-lang/orc-0.4.24[${MULTILIB_USEDEP}] )
+	pango? ( >=x11-libs/pango-1.36.3[${MULTILIB_USEDEP}] )
+	theora? ( >=media-libs/libtheora-1.1.1[encode,${MULTILIB_USEDEP}] )
+	vorbis? ( >=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}] )
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXv-1.0.10[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.12
+	X? (
+		>=x11-proto/videoproto-2.3.1-r1[${MULTILIB_USEDEP}]
+		>=x11-proto/xextproto-7.2.1-r1[${MULTILIB_USEDEP}]
+		>=x11-proto/xproto-7.0.24[${MULTILIB_USEDEP}] )
+"
+RDEPEND+="!<media-libs/gst-plugins-bad-1.11.90:1.0" # rawparse move
+
+multilib_src_configure() {
+	gstreamer_multilib_src_configure \
+		$(use_enable alsa) \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable experimental) \
+		$(use_enable ivorbis) \
+		$(use_enable ogg) \
+		$(use_enable orc) \
+		$(use_enable pango) \
+		$(use_enable theora) \
+		$(use_enable vorbis) \
+		$(use_enable X x) \
+		$(use_enable X xshm) \
+		$(use_enable X xvideo) \
+		--enable-iso-codes \
+		--enable-zlib \
+		--disable-debug \
+		--disable-examples \
+		--disable-static
+	# cdparanoia and libvisual are split out, per leio's request
+
+	# bug #366931, flag-o-matic for the whole thing is overkill
+	if [[ ${CHOST} == *86-*-darwin* ]] ; then
+		sed -i \
+			-e '/FLAGS = /s|-O[23]|-O1|g' \
+			gst/audioconvert/Makefile \
+			gst/volume/Makefile || die
+	fi
+
+	if multilib_is_native_abi; then
+		local x
+		for x in libs plugins; do
+			ln -s "${S}"/docs/${x}/html docs/${x}/html || die
+		done
+	fi
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS NEWS README RELEASE"
+	einstalldocs
+	prune_libtool_files --modules
+}
diff --git a/media-libs/gst-plugins-base/metadata.xml b/media-libs/gst-plugins-base/metadata.xml
new file mode 100644
index 0000000..1d80bb2
--- /dev/null
+++ b/media-libs/gst-plugins-base/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="project">
+	<email>gstreamer@gentoo.org</email>
+	<name>GStreamer package maintainers</name>
+</maintainer>
+<use>
+	<flag name="ivorbis">Enable integer based vorbis decoder</flag>
+	<flag name="pango">Enable pango GStreamer plugin</flag>
+</use>
+</pkgmetadata>
diff --git a/media-libs/gst-plugins-good/Manifest b/media-libs/gst-plugins-good/Manifest
new file mode 100644
index 0000000..9bb692a
--- /dev/null
+++ b/media-libs/gst-plugins-good/Manifest
@@ -0,0 +1 @@
+DIST gst-plugins-good-1.12.3.tar.xz 3487448 SHA256 13e7f479296891fef5a686438f20ba7d534680becf2269ecc5ee24aa83b45f03 SHA512 8ed96d2b2c8724659cf8163be5246ec30c8a92d70fc6632e207ad258cff5624d6fc03576e6e674011bb88a4825c8ce225545bc7e60cdf66a173d9e1d4bfbbaa4 WHIRLPOOL 9255759738e14f9a6aee1122d7f2bd7b23266e33bdc834e2942ac3a1fbb9389fed504d4769c1ab50c35b8a319c351f8373aca8cf09bd138bbaf7bef4fc51894a
diff --git a/media-libs/gst-plugins-good/gst-plugins-good-1.12.3-r1.ebuild b/media-libs/gst-plugins-good/gst-plugins-good-1.12.3-r1.ebuild
new file mode 100644
index 0000000..dc769e7
--- /dev/null
+++ b/media-libs/gst-plugins-good/gst-plugins-good-1.12.3-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GST_ORG_MODULE="gst-plugins-good"
+
+inherit eutils flag-o-matic gstreamer
+
+DESCRIPTION="Basepack of plugins for GStreamer"
+HOMEPAGE="https://gstreamer.freedesktop.org/"
+
+LICENSE="LGPL-2.1+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="+orc +experimental"
+
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-base-${PV}:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-${PV}:${SLOT}[${MULTILIB_USEDEP}]
+	>=app-arch/bzip2-1.0.6-r4[${MULTILIB_USEDEP}]
+	>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+	orc? ( >=dev-lang/orc-0.4.17[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.12
+"
+
+multilib_src_configure() {
+	# Always enable optional bz2 support for matroska
+	# Always enable optional zlib support for qtdemux and matroska
+	# Many media files require these to work, as some container headers are often
+	# compressed, bug #291154
+	gstreamer_multilib_src_configure \
+		$(use_enable experimental) \
+		--enable-bz2 \
+		--enable-zlib \
+		--disable-examples \
+		--with-default-audiosink=autoaudiosink \
+		--with-default-visualizer=goom
+
+	if multilib_is_native_abi; then
+		ln -s "${S}"/docs/plugins/html docs/plugins/html || die
+	fi
+
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS ChangeLog NEWS README RELEASE"
+	einstalldocs
+	prune_libtool_files --modules
+}
diff --git a/media-libs/gst-plugins-ugly/Manifest b/media-libs/gst-plugins-ugly/Manifest
new file mode 100644
index 0000000..6342f9c
--- /dev/null
+++ b/media-libs/gst-plugins-ugly/Manifest
@@ -0,0 +1 @@
+DIST gst-plugins-ugly-1.12.3.tar.xz 903784 SHA256 e88ca584c94ea78eeecbf3af00ef7f134b66bdee7408aa4aa6c547235e060052 SHA512 9ca5769c325df3d2d97ba83d785fab08da5119f6d26c4ac4db72853af143477ea8fb7087464a8614b6e59f384463ac01087ee76cec2af8acd80a4dc15e392e34 WHIRLPOOL e908fb96fc5694c10c16b7e5aeae4a6f7945aaa324074cacc3ec10b84b53ef738ee8c77d6f0983a02e7868275ba26ada14153d7046d85bfdb57f310e59793657
diff --git a/media-libs/gst-plugins-ugly/gst-plugins-ugly-1.12.3-r1.ebuild b/media-libs/gst-plugins-ugly/gst-plugins-ugly-1.12.3-r1.ebuild
new file mode 100644
index 0000000..8b04f88
--- /dev/null
+++ b/media-libs/gst-plugins-ugly/gst-plugins-ugly-1.12.3-r1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GST_ORG_MODULE="gst-plugins-ugly"
+
+inherit eutils gstreamer
+
+DESCRIPTION="Basepack of plugins for gstreamer"
+HOMEPAGE="https://gstreamer.freedesktop.org/"
+
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="+orc +experimental"
+
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-${PV}:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-base-${PV}:${SLOT}[${MULTILIB_USEDEP}]
+	orc? ( >=dev-lang/orc-0.4.17[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.12
+"
+
+multilib_src_configure() {
+	gstreamer_multilib_src_configure $(use_enable experimental)
+
+	if multilib_is_native_abi; then
+		ln -s "${S}"/docs/plugins/html docs/plugins/html || die
+	fi
+
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS ChangeLog NEWS README RELEASE"
+	einstalldocs
+	prune_libtool_files --modules
+}