From 9931e0888b2419326ae10ebbfae532261c5c125f Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Karel=20Ko=C4=8D=C3=AD?= <cynerd@email.cz>
Date: Thu, 30 Jun 2016 16:11:56 +0200
Subject: Fix submodules

---
 vim/bundle/syntastic                           |   1 +
 vim/bundle/syntastic/syntax_checkers/d/dmd.vim | 132 -------------------------
 2 files changed, 1 insertion(+), 132 deletions(-)
 create mode 160000 vim/bundle/syntastic
 delete mode 100644 vim/bundle/syntastic/syntax_checkers/d/dmd.vim

(limited to 'vim/bundle/syntastic/syntax_checkers/d/dmd.vim')

diff --git a/vim/bundle/syntastic b/vim/bundle/syntastic
new file mode 160000
index 0000000..cee74e0
--- /dev/null
+++ b/vim/bundle/syntastic
@@ -0,0 +1 @@
+Subproject commit cee74e0c1af934065fd1b3046e53cda76574f703
diff --git a/vim/bundle/syntastic/syntax_checkers/d/dmd.vim b/vim/bundle/syntastic/syntax_checkers/d/dmd.vim
deleted file mode 100644
index 8897995..0000000
--- a/vim/bundle/syntastic/syntax_checkers/d/dmd.vim
+++ /dev/null
@@ -1,132 +0,0 @@
-"============================================================================
-"File:        d.vim
-"Description: Syntax checking plugin for syntastic.vim
-"Maintainer:  Alfredo Di Napoli <alfredo dot dinapoli at gmail dot com>
-"License:     Based on the original work of Gregor Uhlenheuer and his
-"             cpp.vim checker so credits are dued.
-"             THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
-"             EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
-"             OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
-"             NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
-"             HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
-"             WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
-"             FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
-"             OTHER DEALINGS IN THE SOFTWARE.
-"
-"============================================================================
-
-if exists('g:loaded_syntastic_d_dmd_checker')
-    finish
-endif
-let g:loaded_syntastic_d_dmd_checker = 1
-
-if !exists('g:syntastic_d_compiler_options')
-    let g:syntastic_d_compiler_options = ''
-endif
-
-if !exists('g:syntastic_d_use_dub')
-    let g:syntastic_d_use_dub = 1
-endif
-
-if !exists('g:syntastic_d_dub_exec')
-    let g:syntastic_d_dub_exec = 'dub'
-endif
-
-let s:save_cpo = &cpo
-set cpo&vim
-
-function! SyntaxCheckers_d_dmd_IsAvailable() dict " {{{1
-    if !exists('g:syntastic_d_compiler')
-        let g:syntastic_d_compiler = self.getExec()
-    endif
-    call self.log('g:syntastic_d_compiler =', g:syntastic_d_compiler)
-    return executable(expand(g:syntastic_d_compiler, 1))
-endfunction " }}}1
-
-function! SyntaxCheckers_d_dmd_GetLocList() dict " {{{1
-    if !exists('g:syntastic_d_include_dirs')
-        let g:syntastic_d_include_dirs = s:GetIncludes(self, expand('%:p:h'))
-    endif
-
-    return syntastic#c#GetLocList('d', 'dmd', {
-        \ 'errorformat':
-        \     '%-G%f:%s:,%f(%l): %m,' .
-        \     '%f:%l: %m',
-        \ 'main_flags': '-c -of' . syntastic#util#DevNull(),
-        \ 'header_names': '\m\.di$' })
-endfunction " }}}1
-
-" Utilities {{{1
-
-function! s:GetIncludes(checker, base) " {{{2
-    let includes = []
-
-    if g:syntastic_d_use_dub && !exists('s:dub_ok')
-        let s:dub_ok = s:ValidateDub(a:checker)
-    endif
-
-    if g:syntastic_d_use_dub && s:dub_ok
-        let where = escape(a:base, ' ') . ';'
-
-        let old_suffixesadd = &suffixesadd
-        let dirs = syntastic#util#unique(map(filter(
-            \   findfile('dub.json', where, -1) +
-            \   findfile('dub.sdl', where, -1) +
-            \   findfile('package.json', where, -1),
-            \ 'filereadable(v:val)'), 'fnamemodify(v:val, ":h")'))
-        let &suffixesadd = old_suffixesadd
-        call a:checker.log('using dub: looking for includes in', dirs)
-
-        for dir in dirs
-            try
-                execute 'silent lcd ' . fnameescape(dir)
-                let paths = split(syntastic#util#system(syntastic#util#shescape(g:syntastic_d_dub_exec) . ' describe --import-paths'), "\n")
-                silent lcd -
-                if v:shell_error == 0
-                    call extend(includes, paths)
-                    call a:checker.log('using dub: found includes', paths)
-                endif
-            catch /\m^Vim\%((\a\+)\)\=:E472/
-                " evil directory is evil
-            endtry
-        endfor
-    endif
-
-    if empty(includes)
-        let includes = filter(glob($HOME . '/.dub/packages/*', 1, 1), 'isdirectory(v:val)')
-        call map(includes, 'isdirectory(v:val . "/source") ? v:val . "/source" : v:val')
-        call add(includes, './source')
-    endif
-
-    return syntastic#util#unique(includes)
-endfunction " }}}2
-
-function! s:ValidateDub(checker) " {{{2
-    let ok = 0
-
-    if executable(g:syntastic_d_dub_exec)
-        let command = syntastic#util#shescape(g:syntastic_d_dub_exec) . ' --version'
-        let version_output = syntastic#util#system(command)
-        call a:checker.log('getVersion: ' . string(command) . ': ' .
-            \ string(split(version_output, "\n", 1)) .
-            \ (v:shell_error ? ' (exit code ' . v:shell_error . ')' : '') )
-        let parsed_ver = syntastic#util#parseVersion(version_output)
-        call a:checker.log(g:syntastic_d_dub_exec . ' version =', parsed_ver)
-        if len(parsed_ver)
-            let ok =  syntastic#util#versionIsAtLeast(parsed_ver, [0, 9, 24])
-        endif
-    endif
-
-    return ok
-endfunction " }}}2
-
-" }}}1
-
-call g:SyntasticRegistry.CreateAndRegisterChecker({
-    \ 'filetype': 'd',
-    \ 'name': 'dmd' })
-
-let &cpo = s:save_cpo
-unlet s:save_cpo
-
-" vim: set sw=4 sts=4 et fdm=marker:
-- 
cgit v1.2.3