EAPI=7

inherit acct-user

DESCRIPTION="Personal user for Cynerd"
IUSE="desktop hw-access docker lxd cups wireshark roccat"

ACCT_USER_ID=1000
ACCT_USER_SHELL=/bin/zsh
ACCT_USER_HOME=/home/cynerd
ACCT_USER_GROUPS=(
	cynerd
	wheel
)

DEPEND="
	sys-apps/shellrc[zsh]
	desktop? (
		acct-group/audio
		acct-group/video
		acct-group/input
		acct-group/plugdev
		media-sound/pulseaudio[system-wide]
	)
	hw-access? ( acct-group/usb )
	docker? ( acct-group/docker )
	lxd? ( app-emulation/lxd )
	cups? ( net-print/cups )
	wireshark? ( net-analyzer/wireshark )
	roccat? ( sys-apps/roccat-tools )
"

acct-user_add_deps

pkg_setup() {
	ACCT_USER_GROUPS+=( users portage )
	use desktop && \
		ACCT_USER_GROUPS+=( audio video input plugdev pulse pulse-access )
	use hw-access && \
		ACCT_USER_GROUPS+=( uucp usb )
	use docker && \
		ACCT_USER_GROUPS+=( docker )
	use lxd && \
		ACCT_USER_GROUPS+=( lxd )
	use cups && \
		ACCT_USER_GROUPS+=( lp lpadmin )
	use wireshark && \
		ACCT_USER_GROUPS+=( wireshark )
	use roccat && \
		ACCT_USER_GROUPS+=( roccat )
	true
}

src_install() {
	acct-user_src_install

	insinto "${ACCT_USER_HOME}/.ssh"
	insopts -m644
	doins "${FILESDIR}/authorized_keys"
}