From c16bd18594cd8a4218ef3e96f594a8b1b4e6014c Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Karel=20Ko=C4=8D=C3=AD?= <cynerd@email.cz>
Date: Fri, 15 Mar 2019 21:18:15 +0100
Subject: dev-python/jedi: update to latest upstream version

---
 dev-python/jedi/Manifest           |  1 +
 dev-python/jedi/jedi-0.13.3.ebuild | 62 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)
 create mode 100644 dev-python/jedi/Manifest
 create mode 100644 dev-python/jedi/jedi-0.13.3.ebuild

(limited to 'dev-python/jedi')

diff --git a/dev-python/jedi/Manifest b/dev-python/jedi/Manifest
new file mode 100644
index 0000000..459d7ba
--- /dev/null
+++ b/dev-python/jedi/Manifest
@@ -0,0 +1 @@
+DIST jedi-0.13.3.tar.gz 361575 BLAKE2B 2eac24178ffb5c8676ae70fd4d15689945d66ef8971cc318821d475c6d08ab3ea65f9d8e2f64a6f5de3a9bedf5e9afd61545c00d1e2a5396529de1697d51ad99 SHA512 b4327a5485cecf8b9a6e403a3f0d8f8484fbb15a32a60fe94c0bbb2f7f2452368a6bfdf4a0fd008fbb8b7d27063eac6d8e52f0f06f237e2009bef196d85dfefb
diff --git a/dev-python/jedi/jedi-0.13.3.ebuild b/dev-python/jedi/jedi-0.13.3.ebuild
new file mode 100644
index 0000000..354e2b1
--- /dev/null
+++ b/dev-python/jedi/jedi-0.13.3.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Autocompletion library for Python"
+HOMEPAGE="https://github.com/davidhalter/jedi"
+SRC_URI="https://github.com/davidhalter/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="doc test"
+
+RDEPEND=">=dev-python/parso-0.3.1[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx )
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		${RDEPEND}
+	)"
+
+python_prepare_all() {
+	# speed tests are fragile
+	rm test/test_speed.py || die
+
+	# 'path' completion test does not account for 'path' being a valid
+	# package (i.e. dev-python/path-py)
+	# https://github.com/davidhalter/jedi/issues/1210
+	sed -i -e '/path.*not in/d' test/test_evaluate/test_imports.py || die
+
+	# no clue why it fails but we don't really care about .pyc files
+	# without sources anyway
+	rm test/test_evaluate/test_pyc.py || die
+
+	# our very useful patching changes libdir for no good reason
+	sed -i -e "/site_pkg_path/s:'lib':& if virtualenv.version_info >= (3,7) else '$(get_libdir)':" \
+		test/test_evaluate/test_sys_path.py || die
+
+	# this super-secret feature of py3.4 apparently doesn't work for us
+	sed -i -e 's:test_init_extension_module:_&:' \
+		test/test_evaluate/test_extension.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	py.test -vv jedi test || die "Tests failed under ${EPYTHON}"
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( "${S}"/docs/_build/html/. )
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3