From 76bfb1b7b752d9f77e5e1eeaa98541a1762016e6 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Karel=20Ko=C4=8D=C3=AD?= <cynerd@email.cz>
Date: Fri, 1 Apr 2022 16:14:13 +0200
Subject: dev-libs/cereal: try to fix build

---
 dev-libs/cereal/cereal-1.3.2-r2.ebuild | 47 ++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 dev-libs/cereal/cereal-1.3.2-r2.ebuild

(limited to 'dev-libs/cereal/cereal-1.3.2-r2.ebuild')

diff --git a/dev-libs/cereal/cereal-1.3.2-r2.ebuild b/dev-libs/cereal/cereal-1.3.2-r2.ebuild
new file mode 100644
index 0000000..1bc40b5
--- /dev/null
+++ b/dev-libs/cereal/cereal-1.3.2-r2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Header-only C++11 serialization library"
+HOMEPAGE="https://uscilab.github.io/cereal/"
+SRC_URI="https://github.com/USCiLab/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="doc? ( app-doc/doxygen )"
+DEPEND="dev-libs/rapidjson"
+
+src_prepare() {
+	if ! use doc ; then
+		sed -i -e '/add_subdirectory(doc/d' CMakeLists.txt || die
+	fi
+
+	# remove bundled rapidjson
+	rm -r include/cereal/external/rapidjson || die 'could not remove bundled rapidjson'
+	sed -i -e 's%^\(#include\) "cereal/external/\(rapidjson/[a-z]\+.h\)"%\1 <\2>%g' include/cereal/archives/json.hpp
+	sed -i -e 's%CEREAL_\(RAPIDJSON_NAMESPACE\)%\1%g' include/cereal/archives/json.hpp
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# TODO: drop bundled doctest, rapidxml (bug #792444)
+
+	local mycmakeargs=(
+		-DBUILD_TESTS=$(usex test)
+
+		# Avoid Boost dependency
+		-DSKIP_PERFORMANCE_COMPARISON=ON
+
+		-DWITH_WERROR=OFF
+	)
+
+	cmake_src_configure
+}
-- 
cgit v1.2.3