2 files changed, 63 insertions, 1 deletions
diff --git a/dev-python/jedi/jedi-0.14.1.ebuild b/dev-python/jedi/jedi-0.14.1.ebuild
new file mode 100644
index 0000000..c139f5b
--- /dev/null
+++ b/dev-python/jedi/jedi-0.14.1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="Autocompletion library for Python"
+HOMEPAGE="https://github.com/davidhalter/jedi"
+SRC_URI="https://pypi.python.org/packages/source/${PN:0:1}/${PN}/${P}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="doc test"
+
+RDEPEND=">=dev-python/parso-0.5.0[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx )
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		${RDEPEND}
+	)"
+
+python_prepare_all() {
+	# speed tests are fragile
+	rm test/test_speed.py || die
+
+	# 'path' completion test does not account for 'path' being a valid
+	# package (i.e. dev-python/path-py)
+	# https://github.com/davidhalter/jedi/issues/1210
+	sed -i -e '/path.*not in/d' test/test_evaluate/test_imports.py || die
+
+	# no clue why it fails but we don't really care about .pyc files
+	# without sources anyway
+	rm test/test_evaluate/test_pyc.py || die
+
+	# our very useful patching changes libdir for no good reason
+	sed -i -e "/site_pkg_path/s:'lib':& if virtualenv.version_info >= (3,7) else '$(get_libdir)':" \
+		test/test_evaluate/test_sys_path.py || die
+
+	# this super-secret feature of py3.4 apparently doesn't work for us
+	sed -i -e 's:test_init_extension_module:_&:' \
+		test/test_evaluate/test_extension.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	py.test -vv jedi test || die "Tests failed under ${EPYTHON}"
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( "${S}"/docs/_build/html/. )
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/jedi/jedi-0.15.1.ebuild b/dev-python/jedi/jedi-0.15.1.ebuild
index d99e815..c139f5b 100644
--- a/dev-python/jedi/jedi-0.15.1.ebuild
+++ b/dev-python/jedi/jedi-0.15.1.ebuild
@@ -2,7 +2,7 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
-PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} )
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7,8} )
 
 inherit distutils-r1